home *** CD-ROM | disk | FTP | other *** search
/ Wonky Flux Batch 2019 02 / Wonky_Flux_Batch_2019-02.zip / Wonky Flux Batch 2019-02 / 093 - Land of Spur.dsk / SPUR.SHOP.S < prev    next >
Text File  |  2019-02-17  |  20KB  |  564 lines
  1.                          ; _  _  _  _  _  _  _  _  _
  2.                          ;[_][_][_][_][_][_][_][_][_]
  3.                          ;
  4.                          ;       The Land of SPUR 
  5.                          ;
  6.                          ;       (C)opyright 1987
  7.                          ;         Greg W. Davis
  8.                          ;             and
  9.                          ;       Peripherals Plus
  10.                          ;
  11.                          ; 03/14/87             15:41
  12.                          ;___________________________
  13.                          ;           v3.0
  14.                          ;     Spur Shop Segment
  15.                          ; _  _  _  _  _  _  _  _  _
  16.                          ;[_][_][_][_][_][_][_][_][_]
  17.  
  18.           public main1
  19.  
  20.                          ; ***************
  21.                          ; *  Main Menu  *
  22.                          ; ***************
  23.  
  24. main
  25.           gosub set.pa
  26.           print \"Entering the SPUR shoppe area"\
  27.           
  28. main1
  29.           on nocar goto dropped
  30.           free:gosub tim.chk:if (ev-ex)<120 print \"Dusk approaches..."
  31.           if bd gosub scn.dsp
  32.           input \"Shoppe (?=Menu): "i$
  33.           if i$="?" gosub menu:goto main1
  34.           if i$="W" goto armory
  35.           if i$="B" goto bank
  36.           if i$="V" goto wizard
  37.           if i$="S" dy$=dz$+"spur.sub":link dy$,"show2"
  38.           if i$="I" dy$=dz$+"spur.sub":link dy$,"show3"
  39.           if (i$="Q") or (i$="QUIT") goto quit0
  40.           if i$="T" goto termin
  41.           if i$="DM" goto feedback
  42.           if i$="H" then f$=dx$+"spur.help":gosub show.file:goto main1
  43.           if i$="C" then f$=dx$+"spur.winners":gosub show.file:goto main1
  44.           if i$="A" then f$=dx$+"spur.log":gosub show.file:goto main1
  45.           if i$="L" goto plr.list
  46.           if i$="E" then dy$=dz$+"spur.main":cr=1:di=7:link dy$,"travel3"
  47.           if i$="G" goto general
  48.           if (i$="*") and ((info(5)) or (un=dm)) then dy$=ds$+"spur.sysop":link dy$
  49.           print \"Illegal command":goto main1
  50.  
  51. menu
  52.           setint(1):print \s$\'
  53. *^^^^^^^^^*                 *^^^^^^^^^*
  54. [(^^^^^^^)]  ___  ___  ___  [(^^^^^^^)]
  55.           |   o   |___| |__| |__| |___|   o   |
  56.           |                                   |
  57.           |  The Land of SPUR Commands Menu   |
  58.           |:::::::::::::::::::::::::::::::::::|
  59.           |     W: Ye Olde Armory             |
  60.           |     B: Ye Olde Banker             |
  61.           |     V: Visit the Wizard           |
  62.           |     G: General Stores             |
  63.           |     S: Thy Status                 |
  64.           |     I: Thy Inventory              |
  65.           |     E: Enter The Land of SPUR     |
  66.           |:::::::::::::::::::::::::::::::::::|
  67.           | H:Help w/SPUR    L:List Opponents |
  68.           | A:Adventure Log  DM:Ye Olde DM    |
  69.           |     C:Past Conquerors of SPUR     |
  70.           |:::::::::::::::::::::::::::::::::::|
  71.           | Q:Quit to BBS    T:To Oblivion    |
  72.           [][][][][][][][][]*[][][][][][][][][]':setint(""):return
  73.  
  74.                          ; ***************************
  75.                          ; *  Send letter to the DM  *
  76.                          ; ***************************
  77.  
  78. feedback
  79.           dy$=dm$+"mail"
  80.           print \"Feedback to SPUR DM":x=clock(2):clock(2)=0
  81.           print \"Enter Thy message now, Type thee 'done'"
  82.           print "when all is well!"
  83.           edit(0):edit(1)
  84.           if not edit(2) then clock(2)=x:goto main1
  85.           h$="-> Feedback from The Land of SPUR <-"
  86.           print \"Wait...";: ready dy$
  87.           if info(6)<29 print \"Mail bit-map full":goto main1
  88.           print #msg(dm),un:if h$<>"" print #6,h$\
  89.           print #6,"From ->"n1$" (#"un")"
  90.           print #6,"Date ->"date$" "time$\
  91.           copy #8,#6:print #msg(dm),chr$(4);chr$(0);
  92.           msg(dm)=1:update:print ".feedback saved":clock(2)=x
  93.           goto main1
  94.  
  95.                          ; ****************************
  96.                          ; *  List of System Players  *
  97.                          ; ****************************
  98.  
  99. plr.list
  100.           print \"List of players in Game"
  101.           input @2 \"Match letters or CR for all: "i$
  102.           x=1:dy$=dx$+"spur.users"
  103.           a=1:dr$=dx$+"room.level"+str$(a):ready dr$
  104.           open #1,dy$
  105.           gosub plrlist5
  106.           
  107. plrlist1
  108.           position #1,130,x
  109.           input #1,n$,l1,b1,b2,b3,b4
  110.           input #1,n1,n2,n3,n4,n5,n6
  111.           input #1,g1,g2,f,f,f,f,f,f,f1,f2,m,m1
  112.           setint(1)
  113.           if (not l1) goto plrlist4
  114.           if not instr(i$,n$) goto plrlist4
  115.           if x=pn then b2=cl:lo$="Shoppe":m=mm:f2=mk:b4=hp:f1=ep:n1=ps:n2=pt:n3=pi:n4=pe:n5=pw:n6=pd:g1=gh:g2=gl:goto plrlist2
  116.           if b3=0 then lo$="Shoppe":goto plrlist2
  117.           if a<>b2 then dr$=dx$+"room.level"+str$(b2):ready dr$:a=b2
  118.           input #msg(b3),lo$,f
  119.           setint(1)
  120.           
  121. plrlist2
  122.           gosub prt.gold
  123.           print right$("  "+str$(b1),3)"  ";
  124.           print left$(n$+"               ",15)"  ";
  125.           print "$"gd$"   ";
  126.           print right$("   "+str$(f2),4)"    ";
  127.           print right$("   "+str$(m),4)"   ";
  128.           print right$("  "+str$(b2),3)"-"lo$
  129.           
  130. plrlist4
  131.           x=x+1:if (x>np) or (key(1)) close:goto main1
  132.           goto plrlist1
  133.  
  134. plrlist5
  135.           print \\" #   Adventurer       Gold/Hand    Kills  Moves   Dungeon Level/Room"
  136.           print "---  ---------------  ----------   -----  -----   -----------------------------"
  137.           return
  138.           
  139.                          ; *****************************************
  140.                          ; *  Buy Weapon/Protection - Sell Weapon  *
  141.                          ; *****************************************
  142.           
  143. armory
  144.           print \'
  145. Wouldst   thou be interested in
  146. [P]rotection or [W]eapondry? ';
  147.           input @2 i$
  148.           if i$="P" goto protect
  149.           if i$="W" goto weapons0
  150.           print \"Then BEGONE!!":goto main1
  151.  
  152. weapons0
  153.           dy$=dx$+"weapons":open #1,dy$
  154.           position #1,34,0:input #1,nw
  155. weapons
  156.           print \"Speak "n1$"!"
  157.           input @2\"Wouldst Thou [B]uy or [S]ell? "i$
  158.           if i$="B" goto buy.wep
  159.           if i$="S" goto sel.wep
  160.           print \"Then BEGONE!!":goto wp.exit
  161.  
  162.                          ; ******************
  163.                          ; *  Buy a Weapon  *
  164.                          ; ******************
  165.  
  166. buy.wep
  167.           if xw<6 goto buy1
  168.           print \'
  169. I         am sorry, but you have no room for
  170. more      weapons.  Do you wish to sell a
  171. weapon?   '              ;:input @0 i$
  172.           if i$<>"Y" goto wp.exit
  173.           goto sel.wep
  174.           
  175. buy1
  176.           print \'
  177. Excellent! Choose Thee well!! From mine
  178. hands     I have crafted this list of fine
  179. weapons!'
  180. buy2
  181.           input @2\"Your Choice (?=List): "i$
  182.           if i$="?" gosub wep.list:goto buy2
  183.           if i$="" goto weapons
  184.           x=val(i$):if (x<1) or (x>wc) goto buy2
  185.           position #1,34,x
  186.           input #1,cb$:if cb$<>"2" print \"Weapon not available for sale!":goto buy2
  187.           input #1,w$\s,d,v:w$=mid$(w$,3)
  188.           print \"You chose "w$" for "v" gold"\
  189.           xa$=right$("000"+str$(x),3)+","
  190.           a=instr(xa$,xw$)
  191.           if a print \'
  192. I         see that you already possess this
  193. weapon.    You may NOT buy another.':goto buy2
  194.           input @0"Correct? "i$:if i$<>"Y" goto buy2
  195.           g3=gh:g4=gl:g1=0:g2=v:gosub chk.gold
  196.           if a=0 print \"Sorry to say, but you do not have"\"enough gold at hand":goto buy2
  197.  
  198. buy4
  199.           xw=xw+1:xw$=xw$+xa$
  200.           if x<=10 goto buy5
  201.           nw=nw-1
  202.           position #1,34,x:print #1,0
  203. buy5
  204.           print \"DONE!"
  205.           gosub sub.gold:g1=gh:g2=gl:gosub prt.gold:print \"You now have "gd$" in gold."
  206.           if xw=6 print \"No more room for weapons!":goto buy.wep:else goto buy2
  207.  
  208.                          ; *******************
  209.                          ; *  Sell a Weapon  *
  210.                          ; *******************
  211.  
  212. sel.wep
  213.           wr$=""
  214.           x=0:if xw=0 print \"No weapons.":goto weapons
  215.           print \"Sell which weapon:"\\
  216.           for i=1 to xw:y=(i*4)-3:x=val(mid$(xw$,y))
  217.           position #1,34,x:input #1,cb$\w$:w$=mid$(w$,3)
  218.           print i". "w$
  219.           next
  220.           
  221.           input @2\"Which : "i$:if i$="" goto weapons:else x=val(i$)
  222.           if (x<1) or (x>xw) goto sel.wep
  223.           y=(x*4)-3
  224.           x=val(mid$(xw$,y))
  225.           if nw=25 print \"My weapons inventory is full.":goto weapons
  226.           position #1,34,x:input #1,cb$\w$\s,d,v
  227.           if cb$="2" print \"I already have a "mid$(w$,3)".":goto weapons
  228.           a=v/16:l=a*pi:if l=>v then l=a*14
  229.           if pi=0 then l=a
  230.           print \"I will give you "l" gold for it."\
  231.           input @0 "Doest Thou accept MY offer? "i$
  232.           if i$<>"Y" goto weapons
  233.           print \"Good!":g2=l:gosub add.gold
  234.           xw=xw-1
  235.           if xw=0 then xw$="":goto wr.weap
  236.           l=len(xw$)
  237.           if y=1 then xw$=mid$(xw$,5):goto wr.weap
  238.           if (y+4)>l then xw$=left$(xw$,y-1):goto wr.weap
  239.           xw$=left$(xw$,y-1)+mid$(xw$,y+4)
  240.           
  241. wr.weap
  242.           nw=nw+1
  243.           position #1,34,x:print #1,"2"
  244.           goto weapons
  245.  
  246.                          ; *** List Weapons ***
  247.  
  248. wep.list
  249.           print \'
  250. The       Weapons Master leads you to a table
  251. where     his handcrafted weapons lay....'\
  252.           b=0:x=1:print
  253. w.list2
  254.           position #1,34,x
  255.           input #1,cb$\w$\s,d,v
  256.           setint(1)
  257.           if cb$<>"2" goto w.list3
  258.           w$=mid$(w$,3)
  259.           print right$("   "+str$(x),3)". "left$(w$+"                    ",20)" - "right$("    "+str$(v),4)" Gold"
  260.           b=b+1
  261. w.list3
  262.           x=x+1:if (b=nw) or (x>wc) return
  263.           if (key(1)) return
  264.           goto w.list2
  265.           
  266. wp.exit
  267.           position #1,34,0
  268.           print #1,nw
  269.           close:goto main1
  270.  
  271.                          ; ***********************
  272.                          ; *  Buy Armor/Shields  *
  273.                          ; ***********************
  274.  
  275. protect
  276.           print \'The Weapons Master greets you and says:
  277.  
  278. "Welcome, Adventurer!! Choose from this
  279.           fine list of protection for your long
  280.           journey!"'\
  281.  
  282.           dy$=dx$+"items":open #1,dy$
  283.           x=1
  284. pro1
  285.           position #1,30,x:input #1,cb$:if cb$="*" goto pro1a
  286.           input #1,it$\it:it=it*100:it$=left$(mid$(it$,3)+"                   ",20)
  287.           print right$("   "+str$(x),3)". "it$" - "right$("     "+str$(it),5)" Gold"
  288. pro1a
  289.           x=x+1:if x>5 goto pro2
  290.           goto pro1
  291. pro2
  292.           if xi=15 print \"You have no room in your pack!":close:goto main1
  293.           input @2\"Your Choice (?=List): "i$:if i$="" close:goto main1
  294.           if i$="?" then x=1:print:goto pro1
  295.           x=val(i$):if (x<1) or (x>5) goto pro2
  296.           position #1,30,x:input #1,cb$:if cb$="*" goto pro2
  297.           input #1,it$\it:it=it*100
  298.           g3=gh:g4=gl:g1=0:g2=it:gosub chk.gold:if a=0 print \"You do not have enough gold.":goto pro2
  299.           a$=mid$(it$,3)
  300.           print \"You choose "a$" for "it" gold? ";:input @0 i$
  301.           if i$<>"Y" goto pro2
  302.           xa$=right$("000"+str$(x),3)+","
  303.           a=instr(xa$,xi$):if a print \"I see you already have "a$"."\"You may buy no more.":goto pro2
  304.           print \"Done!":g2=it:gosub sub.gold
  305.           xi=xi+1:xi$=xi$+xa$:goto pro2
  306.  
  307.                          ; ********************
  308.                          ; *  General Stores  *
  309.                          ; ********************
  310.  
  311. general
  312.           print \'The Stores Master greets you and says:
  313.  
  314. "Welcome, Adventurer!! Have you come to
  315.           buy goods for your journey through the
  316.           Land?" '       ;:input @0 i$
  317.           if i$<>"Y" goto main1
  318.           dy$=dx$+"stores":open #1,dy$
  319.           print \"Good!! What will you have today?"\
  320.           x=1
  321. gen1
  322.           position #1,26,x:input #1,cb$:if cb$="*" goto gen1a
  323.           input #1,gs$\gs:gs$=mid$(gs$,3)
  324.           print right$("   "+str$(x),3)". "left$(gs$+"                    ",18)" - "right$("     "+str$(gs),5)" Gold"
  325. gen1a
  326.           x=x+1:if x>10 goto gen2
  327.           goto gen1
  328. gen2
  329.           if xf=10 print \"You have no room in your pack!":close:goto main1
  330.           input @2\"Your Choice (?=List): "i$:if i$="" close:goto main1
  331.           if i$="?" then x=1:print:goto gen1
  332.           x=val(i$):if (x<1) or (x>10) goto gen2
  333.           position #1,26,x:input #1,cb$:if cb$="*" goto gen2
  334.           input #1,gs$\gs
  335.           g3=gh:g4=gl:g1=0:g2=gs:gosub chk.gold:if a=0 print \"You do not have enough gold.":goto gen2
  336.           a$=mid$(gs$,3)
  337.           print \"You choose "a$" for "gs" gold? ";:input @0 i$
  338.           if i$<>"Y" goto gen2
  339.           xa$=right$("000"+str$(x),3)+","
  340.           a=instr(xa$,xf$):if a print \"I see you already have "a$"."\"You may buy no more.":goto gen2
  341.           print \"Done!":g2=gs:gosub sub.gold
  342.           xf=xf+1:xf$=xf$+xa$:goto gen2
  343.  
  344.                          ; ********************
  345.                          ; *  Ye Olde Banker  *
  346.                          ; ********************
  347.  
  348. bank
  349.           print \"[ Ye Bank of SPUR ]"
  350.           g1=bh:g2=bl:gosub prt.gold:print \"In Account :"gd$" gold"
  351.           g1=gh:g2=gl:gosub prt.gold:print \"In hand    :"gd$" gold"
  352.           input @2\"[D]eposit or [W]ithdraw? "i$:if i$="" goto main1
  353.           if i$="W" goto bank3
  354.           if i$<>"D" goto bank
  355.           input @2 \"[ Deposit ] - How much? "gd$:if gd$="" goto main1
  356.           gosub val.gold:if a=0 print \"Invalid amount!":goto bank
  357.           gosub spl.gold:g3=gh:g4=gl:gosub chk.gold:if a=0 print \"You don't have that much!":goto bank
  358. bank2
  359.           gosub put.gold
  360.           goto bank5
  361. bank3
  362.           input @2 \"[ Withdraw ] - How much? "gd$:if gd$="" goto main1
  363.           gosub val.gold:if a=0 print \"Invalid amount!":goto bank
  364.           gosub spl.gold:g3=bh:g4=bl:gosub chk.gold:if a=0 print \"You don't have that much!":goto bank
  365. bank4
  366.           gosub tak.gold
  367. bank5
  368.           g1=bh:g2=bl:gosub prt.gold:print \"In Account: "gd$" gold"
  369.           g1=gh:g2=gl:gosub prt.gold:print "In hand   : "gd$" gold"\\:goto main1
  370.  
  371.                          ; *******************
  372.                          ; *  Learn a Spell  *
  373.                          ; *******************
  374.           
  375. wizard
  376.           if xs=10 goto wiz2b
  377.           dy$=dx$+"spells"
  378.           print \'
  379. You       enter the cave of the Wizard, a
  380. dis-embodied voice asks.....
  381.  
  382. "Are      you here to learn a spell"? ';
  383.           input @0 i$:if i$<>"Y" print \"Return when you are ready.":goto main1
  384.           print \'
  385. A         scroll appears before you, and the
  386. voice     pronounces...'\\
  387.           x=1:open #1,dy$
  388. wiz1a
  389.           position #1,40,x
  390.           input #1,cb$\q$,q2$,q3,q4
  391.           setint(1)
  392.           if (cb$="*") or (cb$="") goto wiz1b
  393.           print right$("   "+str$(x),3)". "left$(q$+"                    ",20)" - "right$("     "+str$(q4),5)" Gold"
  394. wiz1b
  395.           x=x+1:if (x>sc) or (key(1)) close:goto wiz1c
  396.           goto wiz1a
  397. wiz1c
  398.           print \"Choose carefully your spells to learn."\
  399. wiz2
  400.           input @2\"Learn which spell? (?=List): "i$
  401.           if i$="?" print \md$\:x=1:open #1,dy$:goto wiz1a
  402.           if i$="" goto main1:else x=val(i$)
  403.           if (x<1) or (x>sc) goto wiz2
  404.           
  405.           open #1,dy$:position #1,40,x
  406.           input #1,cb$\q$,q2$,q3,q4:close
  407.           if cb$="*" print \"I do not know that spell.":goto wiz2
  408.           print \"You have chosen "q$" for "q4" gold"
  409.           input @0\"Is this correct? "i$
  410.           if i$<>"Y" goto wiz2
  411.           g3=gh:g4=gl:g1=0:g2=q4:gosub chk.gold
  412.           if a=0 print \"Ye do not have enough gold.":goto wiz2
  413. wiz2b
  414.           if xs=10 print'
  415. I         am sorry but ye have already learned
  416. ten       spells.'\:goto main1
  417. wiz3
  418.           print \"Teaching spell..";
  419.           for a=1 to 50
  420.           if not (a mod 5) print ".";
  421.           next
  422.           gosub sub.gold
  423.           b=56:if pi<5 print \'
  424. Thy       intelligence may hinder thee from
  425. learning  this spell.'\:b=100
  426.           a=random(100):if (a>50) and (a<b) print \'
  427. Thou      hast not paid close attention
  428. to        my lessons.  My efforts to teach
  429. thee      were in vain...':goto wiz2
  430.           print \'
  431. Spell     taught, use it wisely, for it may
  432. only      be used ONCE!'
  433.           xs=xs+1
  434.           a$=right$("000"+str$(x),3)+","
  435.           xs$=xs$+a$
  436.           goto wiz2
  437.           
  438.                          ; ***************
  439.                          ; *  Show File  *
  440.                          ; ***************
  441.  
  442. show.file
  443.           setint(1):print \s$\:copy f$:setint(""):return
  444.  
  445.                          ; **********************
  446.                          ; *  Gold Subroutines  *
  447.                          ; **********************
  448.           
  449. add.gold
  450.           gl=gl+g2:if gl=>10000 then gl=gl-10000:gh=gh+1
  451.           return
  452.           
  453. sub.gold
  454.           if g2>gl then gl=gl+10000:gh=gh-1
  455.           gl=gl-g2:return
  456.           
  457. put.gold
  458.           bh=bh+g1
  459.           bl=bl+g2:if bl=>10000 then bl=bl-10000:bh=bh+1
  460.           if g2>gl then gl=gl+10000:gh=gh-1
  461.           gh=gh-g1:gl=gl-g2
  462.           return
  463.           
  464. tak.gold
  465.           if g2>bl then bl=bl+10000:bh=bh-1
  466.           bh=bh-g1:bl=bl-g2
  467.           gh=gh+g1
  468.           gl=gl+g2:if gl=>10000 then gl=gl-10000:gh=gh+1
  469.           return
  470.           
  471. prt.gold
  472.           a$=str$(g1):gd$="0000":if g1=0 then gd$="    ":a$=" "
  473.           gd$=right$("    "+a$,5)+right$(gd$+str$(g2),4)
  474.           return
  475.           
  476. spl.gold
  477.           gd$=right$("00000000"+gd$,9)
  478.           g1=val(left$(gd$,5)):g2=val(right$(gd$,4))
  479.           return
  480.           
  481. chk.gold
  482.           a=0
  483.           if g3>g1 then a=1:return
  484.           if (g3=g1) and (g4=>g2) then a=1:return
  485.           return
  486.           
  487. val.gold
  488.           l=len(gd$)
  489.           for i=1 to l:a=instr(mid$(gd$,i,1),"0123456789")
  490.           if (not a) then i=l:next:return
  491.           next:return
  492.           
  493.                          ; ***************************
  494.                          ; *  Set Player Attributes  *
  495.                          ; ***************************
  496.           
  497. set.pa
  498.           pa=ps+pd+pt+pi+pw+pe:pa=pa mod 10
  499.           return
  500.           
  501.                          ; **********************
  502.                          ; *  Time Subroutines  *
  503.                          ; **********************
  504.           
  505. tim.chk
  506.           ex=clock(1)-ew:if ex=>ev pop:goto quit1
  507.           return
  508.           
  509.                          ; ************************
  510.                          ; *  Screen Subroutines  *
  511.                          ; ************************
  512.           
  513. scn.dsp
  514.           print #3 @4,23 right$("   "+str$(cl),4)
  515.           print #3 @13,23 right$("    "+str$(cr),4)
  516.           print #3 @21,23 right$("  "+str$(ps),3)
  517.           print #3 @29,23 right$("   "+str$(pt),3)
  518.           print #3 @37,23 right$("   "+str$(pw),3)
  519.           print #3 @4,24 right$("   "+str$(mm),4);
  520.           print #3 @13,24 right$("    "+str$(ep),4);
  521.           print #3 @21,24 right$("  "+str$(pe),3);
  522.           print #3 @29,24 right$("   "+str$(pd),3);
  523.           print #3 @37,24 right$("   "+str$(pi),3);
  524.           print #3 @1,20
  525.           if peek(33)=40 goto scn.rtn
  526.           print #3 @45,23 right$(" "+str$(xf),2)
  527.           print #3 @51,23 right$(" "+str$(xi),2)
  528.           print #3 @57,23 right$(" "+str$(xw),2)
  529.           print #3 @63,23 right$("  "+str$(ar),3)
  530.           print #3 @70,23 right$("  "+str$(sh),3)
  531.           print #3 @77,23 right$("  "+str$(mk),3)
  532.           print #3 @45,24 right$(" "+str$(xp),2);
  533.           print #3 @51,24 right$(" "+str$((ev-ex)/60),2);
  534.           g1=gh:g2=gl:gosub prt.gold:print #3 @57,24 gd$;
  535.           print #3 @70,24 right$("  "+str$(df),3);
  536.           print #3 @77,24 right$("  "+str$(sr),3);
  537. scn.rtn
  538.           print #3 @1,20
  539.           return
  540.  
  541.                          ; ************
  542.                          ; *  Logoff  *
  543.                          ; ************
  544.  
  545. termin
  546.           print \"Terminate Connection"\\"Are you sure? ";
  547.           input @0 " "i$:if i$<>"Y" goto main1
  548.           goto dropped
  549.           
  550.                          ; *****************
  551.                          ; *  Link to BBS  *
  552.                          ; *****************
  553.           
  554. quit0
  555.           input @0\"Leave the Land of SPUR ? "i$
  556.           if i$<>"Y" goto main1
  557. quit1
  558.           dy$=dz$+"spur.logon"
  559.           link dy$,"quit1"
  560.  
  561. dropped
  562.           dy$=dz$+"spur.logon"
  563.           link dy$,"quit3"
  564.